OAuth :: 実際にアクセス

#!/usr/bin/perl

use LWP::UserAgent;
use Digest::HMAC_SHA1;
use CGI;

my $q = CGI->new;

# OAuth Consumer Secret
my $consumer_sec = 'OAuth Consumer Secret';

# OAuth Consumer Key
my $consumer_key = 'OAuth Consumer Key';

# OAuth Access Token
my $oauth_token = 'OAuth Access Token';

# OAuth Access Token Secret
my $oauth_token_secret = 'OAuth Access Token Secret';

# Requestを送るURL
my $url = 'https://www.googleapis.com/urlshortener/v1/url';

# URLへのMETHOD
my $method = 'POST';

# OAuth用パラメータ
my %oauth_param;
$oauth_param{oauth_token} = url_encode($oauth_token);
$oauth_param{oauth_consumer_key} = $consumer_key;

# 署名方法はHMAC-SHA1で。
$oauth_param{oauth_signature_method} = 'HMAC-SHA1';

# タイムスタンプとか
$oauth_param{oauth_timestamp} = time();
$oauth_param{oauth_nonce} = int(rand(2**32)) . int(rand(2**32));

# Signature Base String の作成
my $signature_base = createSigBase($url, $method, \%oauth_param);

# Token Secretを取得済なので、署名キーは今回は
# '<OAuth Consumer Secret>&<OAuth Token Secret>'
my $signature_key = url_encode($consumer_sec) . '&' .  url_encode($oauth_token_secret);

# Signature Base String を、key で署名してURLエンコードして署名を作成
my $signature = url_encode(hmac_sha1($signature_key, $signature_base));

# Authorization: ヘッダ情報の生成
my $auth_param = createAuthParam(\%oauth_param, $signature);

# 準備完了！リクエストの実行！！
my $res = LWP::UserAgent->new->request(
	HTTP::Request->new(
		$method,
		$url,
		HTTP::Headers->new(
			'Authorization' => $auth_param,
			'Content-Type' => 'application/json'
		),
		'{"longUrl": "'.$q->param(longUrl).'"}'
	)
);

print 'Content-type: ' . $res->header('Content-type') . "\n\n";
print $res->content;

exit;

# Signature Baseを作ります
sub createSigBase {
	my ($url, $method, $ref_oauth_param) = @_;
	my $param = '';
	{
		my @op = ();
		foreach my $k (sort(keys(%$ref_oauth_param))) {
			push(@op, $k . '=' . url_encode($ref_oauth_param->{$k}));
		}
		$param = join('&', @op);
	}
	return join('&', ($method, url_encode($url), url_encode($param)));
}

# Authorization: ヘッダの内容を作ります
sub createAuthParam {
	my ($ref_oauth_param, $sig) = @_;
	my @op = ();
	foreach my $k (keys(%$ref_oauth_param)) {
		push(@op, $k . '="' . $ref_oauth_param->{$k} . '"');
	}
	push(@op, 'oauth_signature="' . $sig . '"');
	return 'OAuth ' . join(', ', @op);
}
# hmac_sha1 署名。
sub hmac_sha1 {
	my ($key, $msg) = @_;;
	return Digest::HMAC_SHA1->new($key)->add($msg)->b64digest . '=';
}


# URL エンコード
# http://www.din.or.jp/~ohzaki/perl.htm#JP_Escape を参考にしました。
sub url_encode {
	$_ = shift;
	s/([^a-zA-Z0-9_.!~*'()-])/'%' . uc(unpack('H2', $1))/eg;
	return $_;
}

# URL デコード
# http://www.din.or.jp/~ohzaki/perl.htm#JP_Escape を参考にしました。
# 今回は使いません…
sub url_decode {
	$_ = shift;
	s/%([0-9A-Fa-f][0-9A-Fa-f])/pack('H2', $1)/eg;
	return $_;
}